; bjorke - modified 19 sept 96 
ON OUTCHAT { 
  nodressup GLOBAL 
  { 
     "$1" GREPSUB cmd = 
  } { 
     CHATSTR cmd = 
  } CHATSTR "^@[0-9]*,[0-9]* (.*)" GREPSTR IFELSE 
  { 
      1 nodressup = 
      "No Dressup for You" STATUSMSG 
      "" CHATSTR = 
  } cmd "^nodress" GREPSTR IF 
  { 
      0 nodressup = 
      "Now You Can Be Dressed" STATUSMSG 
      "" CHATSTR = 
  } cmd "^redress" GREPSTR IF 
 { 
  { 
        NBRUSERPROPS n = 
        { 
        0 i = 
        ";pp" 
        { 
          " " i USERPROP ITOA & & 
          i ++ 
        } { i n < } WHILE 
        WHOTARGET PRIVATEMSG 
        } n IF 
    } { 
           "you have to whisper it" statusmsg 
    } WHOTARGET IFELSE 
    0 nodressup = 
    "" chatstr = 
  } cmd "dressup" == IF 
  { 
     NAKED 
     "" CHATSTR = 
  } cmd "^undress" GREPSTR IF 
  { 
   "To dress someone, whisper \"dressup\"" LOCALMSG 
   { "To avoid BEING dressed, say \"nodress\"" LOCALMSG } 60 alarmexec 
   { "To undo \"nodress,\" type \"redress\"" LOCALMSG } 120 alarmexec 
   { "Whisper to only be dressed by your friend" LOCALMSG } 180 alarmexec 
   { 
      { "\"halt\" and \"resume\" for entire room" LOCALMSG } 220 alarmexec 
   } ISWIZARD IF 
   { "Caution: Risque props may get you disconnected without warning!!" 
logmsg } 240 alarmexec 
   "" chatstr = 
  } cmd LOWERCASE "^help" GREPSTR IF 
  { 
     1 ME SETSPOTSTATE 
     "Dressups Halted" STATUSMSG 
     "" CHATSTR = 
  } ISWIZARD cmd "halt" == AND IF 
  { 
     0 ME SETSPOTSTATE 
     "Dressups Resumed" STATUSMSG 
     "" CHATSTR = 
  } ISWIZARD cmd "resume" == AND IF 
} 
ON INCHAT { 
  nodressup GLOBAL 
  { 
     0 ME SETSPOTSTATE 
  } ME GETSPOTSTATE NBRROOMUSERS 2 < AND IF 
  { 
     { 
       "[ " "$1" GREPSUB & " ] SETPROPS" & 
          STRTOATOM EXEC 
     } { 
        "Sorry you can't dress me up" WHOCHAT PRIVATEMSG 
     } nodressup NOT 
       WHOTARGET NOT 
       WHOTARGET WHOCHAT == OR AND 
       ME GETSPOTSTATE NOT AND IFELSE 
  } CHATSTR ";pp (-*[0-9].*)$" GREPSTR 
    WHOCHAT WHOME == NOT AND IF 
} 
ON ENTER { 
  { "To dress someone, whisper \"dressup\"" statusmsg } 60 alarmexec 
  { "To avoid BEING dressed, say \"nodress\"" statusmsg } 120 alarmexec 
  { "To undo \"nodress,\" type \"redress\"" statusmsg } 180 alarmexec 
   { 
      { "\"halt\" and \"resume\" for entire room" STATUSMSG } 220 alarmexec 
   } ISWIZARD IF 
  { "Caution: Risque props may get you disconnected without warning!!" 
logmsg } 240 alarmexec 
}